**Supplementary materials to: Population pharmacokinetics and exposure-response of BTZ-043 for the treatment of tuberculosis.**

Simon E Koele1, Norbert Heinrich2,3,4, Veronique R De Jager5, Julia Dreisbach2,3, Patrick PJ Phillips6, Petra Gross-Demel2,3, Rodney Dawson7, Kim Narunsky7, Leticia M Wildner8, Timothy D McHugh8, Lindsey HM te Brake1, Martin J Boeree9, Andreas H Diacon5, Rob E Aarnoutse1, Michael Hoelscher2,3,4,10, Elin M Svensson1,11

1 Department of Pharmacy, Radboud Institute for Medical Innovation, Radboud University Medical Center, Nijmegen, the Netherlands

2 Division of Infectious Diseases and Tropical Medicine, LMU University Hospital, LMU, Munich, Germany

3 German Center for Infection Research (DZIF), Munich Partner Site, Munich, Germany;

4 Fraunhofer Institute for Translational Medicine and Pharmacology ITMP, Immunology, Infection and Pandemic Research, Munich, Germany

5 TASK, Cape Town, South Africa

6 UCSF Center for Tuberculosis, University of California San Francisco, San Francisco, United States

7 University of Cape Town Lung Institute, Cape Town, South Africa

8 UCL Centre for Clinical Microbiology, London, UK

9 Department of Pulmonary Diseases, Radboud University Medical Centre, Nijmegen, the Netherlands

10 Unit Global Health, Helmholtz Zentrum München, German Research Center for Environmental Health (HMGU), Neuherberg, Germany

11 Department of Pharmacy, Uppsala University, Uppsala, Sweden.

**Overview of content:**


Figure S1: VPC of BTZ-043 stratified on food-type

Figure S2: VPC of M1 stratified on food-type


Figure S3: VPC of M2 stratified on food-type

Pharmacokinetic model code


Pharmacodynamic model code



*Figure S1: Prediction corrected VPC showing the observed 2.5th, 50th, and 97.5th percentiles (lines) and confidence intervals from the PK model. From top left to bottom right: Predicted BTZ-043 concentrations for standard food after dose, standard food, no food, and high-fat food.*



*Figure S2: Prediction corrected VPC showing the observed 2.5th, 50th, and 97.5th percentiles (lines) and confidence intervals from the PK model. From top left to bottom right: Predicted M1 concentrations for standard food after dose, standard food, no food, and high-fat food.*



*Figure S3: Prediction corrected VPC showing the observed 2.5th, 50th, and 97.5th percentiles (lines) and confidence intervals from the PK model. From top left to bottom right: Predicted M2 concentrations for standard food after dose, standard food, no food, and high-fat food.*

**Pharmacokinetic model code:**

$PROBLEM PK BTZ043

$INPUT ID DOSE DAY TIME CMT EVID AMT FLAG DV DOSEX FOOD RACE WT

$DATA ….csv IGNORE=@

$SUBROUTINE ADVAN13 TOL=6

$MODEL NCOMP=9 COMP=(DEPOT) COMP=(DEPOT2) COMP=(BTZ043)

COMP=(TRANS1) COMP=(TRANS2) COMP=(M1) COMP=(M2) COMP=(M2peripheral) COMP=(BTZ043peripheral)

;Data dictionary

;ID = Participant ID

;DOSE = Dose [mg]

;DAY = Day after start of treatment [day]

;TIME = Time after start of treatment [h]

;CMT = Compartment number

;EVID = Event ID

;AMT = Drug amount [mg]

;FLAG = Compound identifier [1=BTZ-043, 2=M1, 3=M2]

;DV = Observed concentration [nM/L]

;DOSEX = Identifier second dose for parallel absorption [0=no, 1=yes]

;FOOD = Type of food administered together with BTZ-043 [0=no food, 1= High fat food, 2=standard food after dose, 3= standard food before dose]

;RACE = Race [1=Cape-colored, 0=other]

;WT = Weight [kg]

$PK

;-----------------------Allometric scaling--------------------------

AlloCL=(WT/70)\*\*0.75

AlloV=(WT/70)\*\*1

;--------------------------Food effects----------------------------

FOOD1 = 0 ; High fat food

IF(FOOD.EQ.1) FOOD1=1

FOOD2 = 0 ; Dose prior to food

IF(FOOD.EQ.2) FOOD2=1

FOOD3= 0 ; Standard food before dose

IF(FOOD.EQ.3) FOOD3=1

WITHFOOD=0

IF(FOOD.EQ.3.OR.FOOD.EQ.1)WITHFOOD=1

;-----------------------Structural parameters----------------------

TVCL = THETA(1)

TVV = THETA(2)

TVKA = THETA(3)

TVMTT = THETA(4)

MTTeff = 1

IF(WITHFOOD.EQ.0)MTTeff = THETA(5)

TVF1 = 1

IF(WITHFOOD.EQ.1)TVF1 = THETA(6)

ALAG2 = THETA(7)

FDose = 1

IF(DOSE.GT.1250)FDose = THETA(8)

F\_highfat = 1

IF(FOOD.EQ.1)F\_highfat = THETA(9)

F\_nofood = 1

IF(FOOD.EQ.0)F\_nofood = THETA(10)

F\_latefood = 1

IF(FOOD.EQ.2)F\_latefood = THETA(11)

errM0 = THETA(12)

TVCLM1 = THETA(13)

TVVM1 = THETA(14)

errM1 = THETA(15)

TVCLM2 = THETA(16)

TVVM2 = THETA(17)

errM2 = THETA(18)

TVQM2 = THETA(19)

TVVpM2 = THETA(20)

CLM2time = THETA(21)

CLeffRace = 1

IF(RACE.EQ.1)CLeffRace = THETA(22)

FM1FOOD = 1

IF(WITHFOOD.EQ.0)FM1FOOD = THETA(23)

TVQM0 = THETA(24)

TVVpM0 = THETA(25)

;---------------------------OCCASION definition---------------------

OCC1 = 0

OCC2 = 0

OCC3 = 0

IF(DAY.EQ.1) OCC1 = 1

IF(DAY.EQ.12.AND.STAGE.EQ.1) OCC2 = 1

IF(DAY.EQ.14) OCC3 = 1

;--------------------------IIV/IOV definition----------------------

IIVCL = ETA(1)

IIVV = ETA(2)

IOVF = ETA(3)\*OCC1 + ETA(4)\*OCC2 + ETA(5)\*OCC3

IOVMTT = ETA(6)\*OCC1 + ETA(8)\*OCC2 + ETA(10)\*OCC3

IOVKA = ETA(7)\*OCC1 + ETA(9)\*OCC2 + ETA(11)\*OCC3

IIVF = ETA(12)

IIVCLM1 = ETA(13)

IIVVM1 = ETA(14)

IIVCLM2 = ETA(15)

IIVVM2 = ETA(16)

;-----------------------------PK parameters-------------------------

;M0

KA = TVKA\* EXP(IOVKA) \* KAeffFOOD

KTR = 1/(TVMTT\*EXP(IOVMTT)\*MTTeff)

CL = TVCL \* EXP(IIVCL) \*AlloCL \* CLeffRace

V = TVV \* EXP(IIVV) \*AlloV

QM0 = TVQM0 \*AlloCL

VpM0 = TVVpM0 \*AlloV

;M1

CLM1 = TVCLM1/FM1FOOD \*EXP(IIVCLM1)\*AlloCL

VM1 = TVVM1/FM1FOOD \*EXP(IIVVM1) \*AlloV

;M2

CLM2timeEff=1

IF(DAY.GT.10)CLM2timeEff=1\*CLM2time

CLM2 = TVCLM2/FM2FOOD \*EXP(IIVCLM2)\*AlloCL \*CLM2timeEff

VM2 = TVVM2/FM2FOOD \*EXP(IIVVM2) \*AlloV

QM2 = TVQM2/FM2FOOD \*AlloCL

VpM2 = TVVpM2/FM2FOOD \*AlloV

;---------------------------Bioavailability-------------------------

F1 = TVF1 \*1000000/431.39 \*EXP(IOVF) \*EXP(IIVF) \*F\_highfat \*F\_nofood \*F\_latefood \*FDose ; DV in nmol/L. AMT in mg. Mw = 431.39 g/mol. To get dose in nmol = 10^6/431.39

F2 = (1- TVF1) \*1000000/431.39 \*EXP(IOVF) \*EXP(IIVF) \*F\_highfat \*F\_nofood \*F\_latefood \*FDose

$DES

DADT(1) = -KTR\*A(1)

DADT(2) = -KA\*A(2)

DADT(3) = KA\*A(5) + KA\*A(2) - CL/V\*A(3) - QM0/V\*A(3)+ QM0/VpM0\*A(9)

DADT(4) = KTR\*A(1) - KTR\*A(4)

DADT(5) = KTR\*A(4) - KA\*A(5)

DADT(6) = CL/V\*A(3) - CLM1/VM1\*A(6)

DADT(7) = CL/V\*A(3) - CLM2/VM2\*A(7)- QM2/VM2\*A(7) + QM2/VpM2\*A(8)

DADT(8) = QM2/VM2\*A(7) - QM2/VpM2\*A(8)

DADT(9) = QM0/V\*A(3) -QM0/VpM0\*A(9)

$ERROR

IF(FLAG.EQ.1)IPRED = A(3)/V

IF(FLAG.EQ.2)IPRED = A(6)/VM1

IF(FLAG.EQ.3)IPRED = A(7)/VM2

W=1

IF(IPRED.NE.0.AND.FLAG.EQ.1) W = SQRT(errM0\*\*2\*IPRED\*\*2)

IF(IPRED.NE.0.AND.FLAG.EQ.2) W = SQRT(errM1\*\*2\*IPRED\*\*2)

IF(IPRED.NE.0.AND.FLAG.EQ.3) W = SQRT(errM2\*\*2\*IPRED\*\*2)

IRES = DV-IPRED

IWRES = IRES/W

Y=IPRED + ERR(1)\*W

$THETA

(0, 300) ; 1 CL

(0, 630) ; 2 V

(0, 1.3) ; 3 Ka

(0, 0.1) ; 4 MTT

(0, 1) ; 5 late food MTT

(0, 0.8,0.9999) ; 6 F1 w food

(0, 2) ; 7 lagtime abs 2

(0, 0.7) ; 8 Fhighdose

(0, 1.8) ; 9 F highfat

(0, 0.6) ; 10 F nofood

(0, 0.7) ; 11 F late food

(0, 0.4) ; 12 prop err M0

(0, 20) ; 13 CLM1

(0, 500) ; 14 VM1

(0, 0.3) ; 15 prop err M1

(0, 30) ; 16 CLM2

(0, 20) ; 17 VM2

(0, 0.2) ; 18 prop err M2

(0, 180) ; 19 QM2

(0, 20) ; 20 VpM2

(0, 0.6) ; 21 CLM2timeEff

(0, 0.8) ; 22 CLeffRace

(0, 0.6) ; 23 FM1food

(0, 50) ; 24 QM0

(0, 200) ; 25 VpM0

$OMEGA

0.1 ; 1 IIV CL

0.1 ; 2 IIV V

$OMEGA BLOCK(1)

0.1 ; 3 IOV F

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(2)

0.3 ; 6 IIV MTT

0.1 0.3 ; 7 IOV KA

$OMEGA BLOCK(2) SAME

$OMEGA BLOCK(2) SAME

$OMEGA

0.1 ; 12 IIV F

0.1 ; 13 IIV CLM1

0.1 ; 14 IIV VM1

0.1 ; 15 IIV CLM2

0.5 ; 16 IIV VM2

$SIGMA 1 FIX

$ESTIMATION METHOD=1 INTER MAXEVAL=9999 NOABORT SIGL=6 NSIG=2 PRINT=1

$COVARIANCE UNCONDITIONAL PRINT=E

**Pharmacodynamic model code:**

$PROB BTZ-043 pharmacodynamic model CFU and TTP observations

$INPUT ID TIME DV FLAG BLQ EVID MDV REP L2 EXMET

$DATA ….csv IGNORE =@

;Data dictionary

;ID =Subject ID

;TIME =Time after start of treatment (h)

;DV =Bacterial load (log10(CFU\*ml-1),log10(TTP))

;FLAG =Biomarker (1=CFU, 2=TTP)

;BLQ =Below limit of quantification (1=yes, 2=no)

;EVID =Event ID

;MDV =Missing dependent variable

;REP =CFU or TTP replicate (1 or 2)

;L2 =L2 data item

;EXMET =Exposure metric

$PRED

;-----------------------Exposure-response---------------------------

EXRES=(1+(EXMET)/median(EXMET)\*THETA(8)) ;impute the median here

;----------------------------- PD model-----------------------------

INTERCEPTCFU = THETA(1) \*EXP(ETA(1))

INTERCEPTTTP = THETA(2) \*EXP(ETA(2))

BETA1BTZCFU = THETA(3) \*EXRES

BETA2BTZCFU = THETA(4) \*EXP(ETA(4))

BETA1BTZTTP = THETA(5) \*EXP(ETA(3))\*EXRES

BETA2BTZTTP = THETA(6) \*EXP(ETA(5))

NODE = THETA(7)

IF(FLAG.EQ.1)THEN

BETA1=BETA1BTZCFU

BETA2=BETA2BTZCFU

ELSE

BETA1=BETA1BTZTTP

BETA2=BETA2BTZTTP

ENDIF

CFU1= INTERCEPTCFU - BETA1\*TIME

CFUatNODE= INTERCEPTCFU - BETA1\*NODE

CFU2= CFUatNODE - BETA2\*(TIME-NODE)

TTP1= INTERCEPTTTP + BETA1\*TIME

TTPatNODE= INTERCEPTTTP + BETA1\*NODE

TTP2= TTPatNODE + BETA2\*(TIME-NODE)

CFU = CFU1

IF (TIME.GT.NODE) CFU= CFU2

TTP = TTP1

IF (TIME.GT.NODE) TTP= TTP2

IF(FLAG.EQ.1) IPRED = CFU

IF(FLAG.EQ.2) IPRED = TTP

;----------- PROBABILITY OF BACTERIAL PRESENCE ---------------------

;Change of negative culture result during first three days on treatment

IF (FLAG.EQ.1) PBAC = 0.009 ;CFU

IF (FLAG.EQ.2) PBAC = 0 ;TTP

;Error model

IF (FLAG.EQ.1.AND.REP.EQ.1) ADDERR = EPS(1)

IF (FLAG.EQ.2.AND.REP.EQ.1) ADDERR = EPS(3)

IF (FLAG.EQ.1.AND.REP.EQ.2) ADDERR = EPS(2)

IF (FLAG.EQ.2.AND.REP.EQ.2) ADDERR = EPS(4)

;----------------------------M3 code--------------------------------

IF (FLAG.EQ.1) SD = SQRT(SIGMA(1,1))

IF (FLAG.EQ.2) SD = SQRT(SIGMA(3,3))

LLOQ=1 ;LLOQ for CFU

ULOQ=LOG10(25\*24) ;ULOQ for TTP

DUMLLOQ=(LLOQ-IPRED)/SD

DUMULOQ=(IPRED-ULOQ)/SD

IF (FLAG.EQ.1) CUMD=PHI(DUMLLOQ)

IF (FLAG.EQ.2) CUMD=PHI(DUMULOQ)

IF (BLQ.EQ.2) THEN

F\_FLAG=0

Y=IPRED + ADDERR

IRES = DV - IPRED

ENDIF

IF (BLQ.EQ.1) THEN

F\_FLAG=1

Y=CUMD+PBAC-(CUMD\*PBAC)

MDVRES = 1

ENDIF

$THETA

(0, 6.2) ;1 INTERCEPTCFUP1

(0, 1.99) ;2 INTERCEPTTTPP1

(0, 0.00667) ;3 B1CFU

(0, 0.00254) ;4 B2CFU

(0, 0.000961) ;5 B1TTP

(0, 0.000438) ;6 B2TTP

(0, 48) FIX ;7 NODE

(0, 794) ; 8 EXRES

$OMEGA BLOCK(3)

0.0225 ;1 INTECEPTCFU

-0.0053 0.0026 ;2 INTECEPTTTP

-0.0185 -0.007 0.211 ;3 SLOPE1TTP

$OMEGA BLOCK(2)

0.462;4 SLOPE2CFU

0.252 0.223;5 SLOPE2TTP

$SIGMA BLOCK(4)

0.301 ; ADD error CFU1

0.281 0.327 ; ADD error CFU2

-0.0184 -0.0199 0.0044 ; ADD error TTP1

-0.0176 -0.0193 0.0033 0.0035 ; ADD error TTP2

$ESTIMATION METHOD=1 INTERACTION LAPLACIAN NUMERICAL SLOW MAXEVAL=9999 NSIG=2 PRINT=1

$COV UNCONDITIONAL